import javafx.stage.*;
import javafx.scene.*;
import javafx.scene.transform.*;
import mathematics.multidimensional.*;
import mathematics.multidimensional.shape.*;


class Paraboloid  extends IMDTransform{

    public override function getDimN(){ 2 }
    public override function getDimM(){ 3 }

    public override function transform (vector:IMDVector):IMDVector {
        var x = vector.getElem( 0 );
        var y = vector.getElem( 1 );

        MDVector{
            dim: 3
            elems: [ x,  y, (x * x + y * y) / 100   ]
        }
    }
}

var dim = 3;

Stage {
    title: "Paraboloid"
    scene: Scene {
        width: 400
        height: 400
        content: [
            MDUniverse{
                dimension: dim
                transforms: Transform.translate(200,200);
                projection: MDMatrix{
                    dimN: 2
                    dimM: dim
                    elems: [
                        [1, 0, 0],
                        [0, 1, 0]
                    ]
                }
                mdtransforms: [
                      MDTransform.rotate(20.0, 0, 1, dim),
                      MDTransform.rotate(70.0, 1, 2, dim),
                ]

                shapes: MDPlotter{
                    mdtransform: Paraboloid {}
                    domain: MDParametrizedSet{
                        dim: 2
                        delta: 5.0
                        start: MDVector{
                            dim: 2
                            elems: [-100, -100]
                        }
                        end: MDVector{
                            dim: 2
                            elems: [100, 100]
                        }
                    }
                }
            }
        ]
    }
}